今日やりたいこと

平面の媒介変数表示（小テストの問題 3 (5)(6) ）．

1次独立と1次従属について

3次元グラフィックスの描画．

球面（円周）のベクトル方程式と媒介変数表示．

平面のベクトル方程式（媒介変数表示）

p = (Subscript[p, 0])+k a + l b

空間内の3点 (Subscript[P, 0])(1, 2, 3)，A(3,1,2)，B(2, 1,3 ) を通る平面の方程式．

Manipulate[
P0={1,2,3};
PA={3,1,2};
PB={2,3,1};
va=PA-P0;
vb=PB-P0;
Show[
ParametricPlot3D[P0+t*va+s*vb,{t,-2,2},{s,-2,2},(*平面のベクトル方程式*)
Mesh->None,(*平面内部の格子を描かない*)
PlotStyle->Opacity[m](*平面を透明にする*)],
Graphics3D[
{
{PointSize[Large],Point[{{0,0,0},P0, PA, PB,P0+k*va+l*vb}]},
Text["(Subscript[P, 0])",P0+{0,0,0.2}],
Text[O,{0,0,0.2}],
Text[A,PA+{0,0,0.2}],
Text[B,PB+{0,0,0.2}],
{Blue,Arrow[{P0,P0+k*va}]},
{Blue,Arrow[{P0,P0+l*vb}]},
{Green,Arrow[{{0,0,0},P0}]},
{Blue,Arrow[{P0,P0+k*va+l*vb}]},
{Red,Arrow[{P0,P0+Cross[va,vb]}]},
{Dashed,Line[{P0+k*va,P0+k*va+l*vb}]},
{Dashed,Line[{P0+l*vb,P0+k*va+l*vb}]}
}
]
],
{{k,1,"ベクトル a の係数 k"},-2,2},{{l,1,"ベクトル b の係数 l"},-2,2},{{m,0.5,"平面の透明度"},0,1}
]

球面のベクトル方程式

球面 = 中心 (Subscript[P, 0])からの距離が一定（半径 r ）な点 P の集まり．つまり

| p - (Subscript[p, 0])| = r

P={x,y,z};
P0={(Subscript[x, 0]),(Subscript[y, 0]),(Subscript[z, 0])};
r=k;
(P-P0).(P-P0)==r^2

曲面の描画 (1)：z = f(x, y)

Plot3D[x と y の関数,{xの動く範囲},{yの動く範囲}]

原点中心，半径1 の球面

(x^2)+ (y^2)+ (z^2)  = 1 ⟺ z = (Sqrt[1-(x^2)-(y^2)])

Plot3D[Sqrt[1-x^2-y^2],{x,-1,1},{y,-1,1}]

曲面の描画 (1)：z = f(x, y)

Manipulate[
Show[
Graphics3D[
{
{PointSize[Large],Point[{k,l,Sqrt[1-k^2-l^2]}]},
{PointSize[Large],Point[{k,l,0}]},
Text["(x, y, 0)",{k,l,-0.1}],
Text["(x, y, (Sqrt[1 - x^2 - y^2]))",{k,l,1-k^2-l^2+0.3}],
{Dashed,Line[{{k,l,0},{k,l,Sqrt[1-k^2-l^2]}}]}
}
],
Plot3D[Sqrt[1-x^2-y^2],{x,-1,1},{y,-1,1},Mesh->None,PlotStyle->Opacity[0.5]]
],{{k,1/2,"x"},-1,1},{{l,1/2,"y"},-1,1}
]

曲面の描画 (2)： f(x, y, z) = 0

ContourPlot3D[x と y と z の関数,{xの動く範囲},{yの動く範囲}, {zの動く範囲}]

原点中心，半径1 の球面

(x^2)+ (y^2)+ (z^2)  = 1

ContourPlot3D[x^2+y^2+z^2==1,{x,-1,1},{y,-1,1}, {z,-1,1}]

曲面の描画 (3)（媒介変数表示）: ( x( t, s) , y( t, s) , z( t, s) )

ParametricPlot3D[{x座標の関数, y座標の関数, z座標の関数},{tの動く範囲},{sの動く範囲}]

原点中心，半径1 の球面

( x, y, z ) = ( cos t  cos s , sin t  cos s , sin s )

ParametricPlot3D[{Cos[t]*Cos[s],Sin[t]*Cos[s],Sin[s]},{t,0,2*Pi},{s,-Pi/2,Pi/2}]

例：円周の媒介変数表示

( x, y ) = ( cos t ,  sin t )

Manipulate[
Show[
ParametricPlot[{Cos[t],Sin[t]},{t,0,2*Pi}],
Graphics[
{
{PointSize[Large],Point[{Cos[k],Sin[k]}]},
Text["cos t",{Cos[k],-0.1}],
Text["sin t",{0.1,Sin[k]}],
{Dashed,Line[{{Cos[k],0},{Cos[k],Sin[k]}}]},
{Dashed,Line[{{0,Sin[k]},{Cos[k],Sin[k]}}]},
{Thick,Line[{{0,0},{Cos[k],Sin[k]}}]}
}
]
],
{{k,Pi/6,"パラメーター t"},0,2*Pi}
]

球面の媒介変数表示（中心が原点，半径1の場合）

Manipulate[
Show[
ParametricPlot3D[{Cos[t]*Cos[s],Sin[t]*Cos[s],Sin[s]},{t,0,2*Pi},{s,-Pi/2,Pi/2},Mesh->None,PlotStyle->Opacity[0.5]],
ParametricPlot3D[{Cos[u],Sin[u],0},{u,0,2*Pi}],
Graphics3D[
{
{PointSize[Large],Point[{Cos[k]*Cos[l],Sin[k]*Cos[l],Sin[l]}]},
{Thick,Line[{{0,0,0},{Cos[k]*Cos[l],Sin[k]*Cos[l],Sin[l]}}]},
{Dashed,Line[{{Cos[k]*Cos[l],Sin[k]*Cos[l],0},{Cos[k]*Cos[l],Sin[k]*Cos[l],Sin[l]}}]},
{Dashed,Line[{{Cos[k]*Cos[l],Sin[k]*Cos[l],0},{0,0,0}}]},
Line[{{0,0,0},{1,0,0}}]
}
]
],
{{k,Pi/6,"パラメーター t"},0,2*Pi},{{l,Pi/6,"パラメーター s"},-Pi/2,Pi/2}
]